JOB  DIVISION 998001                                        04712
               CTL  6651
     *
     * DO A 6100 DIGIT DIVISION AND PRINT RESULT IN MULTIPLE LINES
     *
     HELLO     DCW  @DIVISION  1 / 998001 = 0.       ROLFFSON 08-2023@
     BYE       DCW  @... END OF RUN@
     ZERO      DCW  @0@
     DIVID     DCW  @1@
     DIVIS     DCW  @998001@           * DIVISOR
     DPL       DCW  @099@              * DIGITS PER PRINT LINE
     DIVBUF    EQU  1000               * START OF DIVISION BUFFER
     PEND      DSA  7138               * LAST ADDRESS FOR PRINTOUT 61X99
     DIVEND    EQU  7199               * LAST ADDRESS OF DIVISION BUFFER
     PRINTB    EQU  201
     *
     * PRINT INFO MESSAGE
     START     MCW  HELLO,248
               W
     * PREPARE DIVISION BUFFER
               SW   DIVBUF             * SET WORDMARK AT BEGINNING
               ZA   ZERO,DIVEND        * FILL WITH ZEROES
               MCW  DIVID,DIVBUF+7     * MOVE 1 TO START OF DIVIDENT PART
               D    DIVIS,DIVBUF+7     * DIVIDE BY DIVISOR
     * PREPARE PRINT BUFFER
               SW   PRINTB             * SET WORDMARK AT BEGINNING
     PRINT     MCW  DIVBUF+99,PRINTB+98  * COPY 99 DIGITS TO PRINTBUF
               W                       * PRINT THEM
               C    PRINT+3,PEND       * CHECK IF LAST DIGIT REACHED
               MA   DPL,PRINT+3        * INCREASE MOVE SRC BY 99
               BU   PRINT              * IF NOT END, PRINT NEXT LINE
     * PRINT BYE MESSAGE
               CS   PRINTB+98
               MCW  BYE,PRINTB+14
               W
               H         
               END  START